@ECHO OFF

rem WinRAR.exeのフルパスを入力↓
SET RAR="D:\Program Files\WinRAR\WinRAR.exe"

rem 解凍先を入力↓
SET OUT="R:\"

cls
echo.
echo ** 解凍 **
echo 作業場所 %OUT% 
echo.
echo [1] 全て
echo [2] 危険拡張子を除外
echo [3] 画像のみ
echo [4] 文章のみ
echo [9] 処理中止
echo.
choice /c:12349
IF ERRORLEVEL 5 GOTO END1
IF ERRORLEVEL 4 GOTO OUT4
IF ERRORLEVEL 3 GOTO OUT3
IF ERRORLEVEL 2 GOTO OUT2
IF ERRORLEVEL 1 GOTO OUT1

rem /c:12349 は選択する各数値、英字も入力可能
rem 例えば3なら先頭から三番目、ERRORLEVEL 3 で OUT3 へ飛びます
rem /t:9,15 は15秒後に[9]を選ぶ、9は先頭から五番目、ERRORLEVEL 5 で END1 へ飛びます

:OUT1
rem 全て解凍

rem ファイル名がないなら END1へ移動
if ""%1""=="""" goto END1

rem %RAR%はWinRARが格納されてる場所
rem xは解凍、-xで指定されたファイルは解凍しない
rem %1はドラッグした圧縮書庫名
rem %OUT%は解凍先
%RAR% x -xThumbs.d? %1 %OUT%

rem ドラッグされたファイルが複数ならファイル名を繰り上げる
shift

rem OUT1へ戻る
goto OUT1

:OUT2
rem 危険拡張子を除外解凍

if ""%1""=="""" goto END1
%RAR% x -x*.exe -x*.scr -x*.vbs -x*.bat -x*.com -x*.pif -x*.cmd -x*.lnk -xThumbs.d? %1 %OUT%
shift
goto OUT2

:OUT3
rem 画像のみ解凍

if ""%1""=="""" goto END1

rem -nで指定したファイルのみを解凍
%RAR% x -n*.bmp -n*.png -n*.jpg -n*.jpeg -n*.gif %1 %OUT%

shift
goto OUT3

:OUT4
rem 文章のみ解凍

if ""%1""=="""" goto END1
%RAR% x -n*.txt -n*.htm -n*.html %1 %OUT%
shift
goto OUT4

:END1
rem 終了